25.3.4 VUMAT

25.3.4 VUMAT

25.3.4 VUMAT

User subroutine to define material behavior.

定义材料本构用户子程序

Product: ABAQUS/Explicit  

Warning:  The use of this user subroutine generally requires considerable expertise. You are cautioned that the implementation of any realistic constitutive model requires extensive development and testing. Initial testing on a single-element model with prescribed traction loading is strongly recommended.

注意：用户子程序的使用通常需要一定的专长。用户需要知道执行任何实际的本构模型需要大量的试验数据。强烈建议用户对用户子程序进行在指定拉力作用下单个单元的验证测试。

The component ordering of the symmetric and nonsymmetric tensors for the three-dimensional case using C3D8R elements is different from the ordering specified in “Three-dimensional solid element library,” Section 14.1.4, and the ordering used in ABAQUS/Standard.

C3D8R单元三维轴对称及非轴对称张量成分顺序与“Three-dimensional solid element library,” Section 14.1.4及ABAQUS/Standard中指定的顺序不同。

References

∙ “User-defined mechanical material behavior,” Section 12.8.1

∙ *USER MATERIAL

Overview

User subroutine VUMAT:

用户子程序VUMAT

∙ is used to define the mechanical constitutive behavior of a material;

∙ 用来定义材料的力学本构关系

∙ will be called for blocks of material calculation points for which the material is defined in a user subroutine (“Material data definition,” Section 9.1.2);

∙ 可以被用户子程序定义材料计算点调用

∙ can use and update solution-dependent state variables;

∙ 可以使用和更新结果依赖状态变量

∙ can use any field variables that are passed in;

∙ 可以使用传入的任何场变量

∙ is described further in “User-defined mechanical material behavior,” Section 12.8.1; and

∙ 在“User-defined mechanical material behavior,” Section 12.8.1中详细论述；

∙ cannot be used in an adiabatic analysis.

∙ 可以被用于绝热分析

Component ordering in tensors 张量组成顺序

The component ordering depends upon whether the tensor is symmetric or nonsymmetric.

张量组成顺序取决于其是否为对称或非对称张量。

Symmetric tensors 对称张量

For symmetric tensors such as the stress and strain tensors, there are ndir+nshr components, and the component order is given as a natural permutation of the indices of the tensor. The direct components are first and then the indirect components, beginning with the 12-component. For example, a stress tensor contains ndir direct stress components and nshr shear stress components, which are passed in as

对于如同应力及应变张量等的对称张量，含有ndir+nshr分量，分量的序号按张量索引号的自然排序给出。首先是直接分量，然后是从12分量开始的间接分量。例如，包含ndir正应力分量及nshr的剪应力张量的应力张量被按照下面的顺序传入

The shear strain components in user subroutine VUMAT are stored as tensor components and not as engineering components; this is different from user subroutine UMAT in ABAQUS/Standard, which uses engineering components.

Nonsymmetric tensors 非对称张量

For nonsymmetric tensors there are ndir+2*nshr components, and the component order is given as a natural permutation of the indices of the tensor. The direct components are first and then the indirect components, beginning with the 12-component. For example, the deformation gradient is passed as

对于非对称张量含有ndir+2*nshr分量，分量的顺序按照张量索引号的自然排序给出。首先是直接分量，其次是从12分量开始的间接分量。例如，位移剃度按照下面的顺序传递

Initial calculations and checks 最初计算和检查

In the data check phase of the analysis ABAQUS/Explicit calls user subroutine VUMAT with a set of fictitious strains and a totalTime and stepTime both equal to 0.0. This is done as a check on your constitutive relation and to calculate the equivalent initial material properties, based upon which the initial elastic wave speeds are computed.

在ABAQUS/Explicit调用用户子程序VUMAT分析的数据检查阶段,小应变、总时间及时间步都为0。这作为对用户本构关系的一个检查，基于计算得到的初始材料波速来计算等效初始材料属性。

Defining local orientations 定义局部方向

All stresses, strains, stretches, and state variables are in the orientation of the local material axes. These local material axes form a basis system in which stress and strain components are stored. This represents a corotational coordinate system in which the basis system rotates with the material. If a user-specified coordinate system (“Orientations,” Section 2.2.5) is used, it defines the local material axes in the undeformed configuration.

所有的应力、应变、延伸及状态变量均按局部材料轴的方向。这些局部材料轴形成一个应力与应变分量存储的基本系统。即这个基本系是随着材料联合转动的坐标系。如果使用用户指定坐标系，则它在无变形结构中定义局部材料轴。

Special considerations for various element types

不同单元类型的特殊考虑

The use of user subroutine VUMAT requires special consideration for various element types.

用户子程序VUMAT的使用需要对不同的单元类型进行特殊的考虑。

Shell and plane stress elements

壳及平面应力单元

You must define the stresses and internal state variables. In the case of shell or plane stress elements, you must define strainInc(*,3), the thickness strain increment. The internal energies can be defined if desired. If they are not defined, the energy balance provided by ABAQUS/Explicit will not be meaningful.

用户必须定义应力和初始状态变量。在壳或平面应力单元的情况下，用户必须定义应变包括（*,3），厚度应变增量。如果需要的话还需要定义初始能量。如果没有定义，那么ABAQUS/Explicit提供的能量平衡将没有意义。

Shell elements

壳单元

When VUMAT is used to define the material response of shell elements, ABAQUS/Explicit cannot calculate a default value for the transverse shear stiffness of the element. Hence, you must define the element's transverse shear stiffness. See “Shell section behavior,” Section 15.6.4, for guidelines on choosing this stiffness.

当使用VUMAT定义壳单元的材料响应时，ABAQUS/Explicit不能计算单元的缺省横向剪切刚度。因此，用户需要定义单元的横向剪切刚度。关于选择横行剪切刚度的详细资料请参考“Shell section behavior,” Section 15.6.4

Beam elements

梁单元

For beam elements the stretch tensor and the deformation gradient tensor are not available. For beams in space you must define the thickness strains, strainInc(*,2) and strainInc(*,3). strainInc(*,4) is the shear strain associated with twist. Thickness stresses, stressNew(*,2) and stressNew(*,3), are assumed to be zero and any values you assign are ignored.

对于梁单元不能使用拉伸张量及位移剃度张量。对于空间梁，用户必须定义厚度应变、应变增量（*，2）及应变增量（*，3）。应变增量（*，4）时与扭曲有关的剪应变。厚度应力，（*，2）及（*，3）假定为0，并且用户分配的任何相关张量都被忽略。

Deformation gradient 位移剃度

The polar decomposition of the deformation gradient is written as , where and are the right and left symmetric stretch tensors, respectively. The constitutive model is defined in a corotational coordinate system in which the basis system rotates with the material. All stress and strain tensor quantities are defined with respect to the corotational basis system. The right stretch tensor, , is used. The relative spin tensor represents the spin (the antisymmetric part of the velocity gradient) defined with respect to the corotational basis system.

位移剃度写成，其中及分别为右边及左边的对称拉伸张量。本构模型定义为联合旋转坐标系，在该坐标系中基系随着材料转动。所有的应力和应变张量值按照联合旋转坐标系定义。使用右边的拉伸位移。相应的旋转张量代表与联合旋转基系相应的转动。

Special considerations for hyperelasticity

超弹性的特殊考虑

Hyperelastic constitutive models in VUMAT should be defined in a corotational coordinate system in which the basis system rotates with the material. This is most effectively accomplished by formulating the hyperelastic constitutive model in terms of the stretch tensor, , instead of in terms of the deformation gradient, . Using the deformation gradient can present some difficulties because the deformation gradient includes the rotation tensor and the resulting stresses would need to be rotated back to the corotational basis.

在VUMAT中的超弹性本构模型可以被定义在联合选择坐标系中。这可以通过用拉伸张量表示的超弹性本构模型很好的实现，而不是使用位移剃度来表示。使用位移剃度可能会带来一些困难，因为位移剃度包括旋转张量并且导致应力需要选择返回到联合旋转基系。

Objective stress rates目标应力率

The Green-Naghdi stress rate is used when the mechanical behavior of the material is defined using user subroutine VUMAT. The stress rate obtained with user subroutine VUMAT may differ from that obtained with a built-in ABAQUS material model. For example, most material models used with solid (continuum) elements in ABAQUS/Explicit employ the Jaumann stress rate. This difference in the formulation will cause significant differences in the results only if finite rotation of a material point is accompanied by finite shear. For a discussion of the objective stress rates used in ABAQUS, see “Stress rates,” Section 1.5.3 of the ABAQUS Theory Manual.

在用户子程序VUMAT中使用Green-Naghdi应力率来定义材料的力学本构关系。通过用户子程序VUMAT获得的应力率可能会与在ABAQUS建立的材料模型获得的应力率有所不同。例如，在ABAQUS/Explicit中大多数实体（连续）单元材料模型使用Jaumann应力率。只要材料点的有限旋转伴随有限剪切，这种表达方式的不同将导致计算结果的明显差异。关于ABAQUS中使用的目标应力率的详细讨论参考“Stress rates,” Section 1.5.3 of the ABAQUS Theory Manual.

Material point deletion 材料点删除

Material points that satisfy a user-defined failure criterion can be deleted from the model (see “User-defined mechanical material behavior,” Section 12.8.1). You must specify the state variable number controlling the element deletion flag when you allocate space for the solution-dependent state variables, as explained in “User-defined mechanical material behavior,” Section 12.8.1. The deletion state variable should be set to a value of one or zero in VUMAT. A value of one indicates that the material point is active, while a value of zero indicates that ABAQUS/Explicit should delete the material point from the model by setting the stresses to zero. The structure of the block of material points passed to user subroutine VUMAT remains unchanged during the analysis; deleted material points are not removed from the block. ABAQUS/Explicit will pass zero stresses and strain increments for all deleted material points. Once a material point has been flagged as deleted, it cannot be reactivated.

满足用户定义的破坏准则的材料点可以被从模型中删除（参考“User-defined mechanical material behavior,” Section 12.8.1)。当用户给结果依赖状态变量分配空间时，用户需要指定控制单元删除标示的状态变量号，在“User-defined mechanical material behavior,” Section 12.8.1中进行详细说明。在VUMAT中删除状态变量可以被赋予1或者0。1表示材料点时激活的，0表示ABAQUS/Explicit将通过设定应力为0删除材料点。在分析过程中传递给用户子程序VUMAT的材料点结构保持不变；删除的材料点没有从块中移走。ABAQUS/Explicit将传递0应力及应变给所有删除的材料点。一旦一个材料点被标示为删除，该材料点将不能够被再次激活。

User subroutine interface 用户子程序

subroutine vumat(

C Read only (unmodifiable)variables -

1 nblock, ndir, nshr, nstatev, nfieldv, nprops, lanneal,

2 stepTime, totalTime, dt, cmname, coordMp, charLength,

3 props, density, strainInc, relSpinInc,

4 tempOld, stretchOld, defgradOld, fieldOld,

5 stressOld, stateOld, enerInternOld, enerInelasOld,

6 tempNew, stretchNew, defgradNew, fieldNew,

C Write only (modifiable) variables -

7 stressNew, stateNew, enerInternNew, enerInelasNew )

C

include 'vaba_param.inc'

C

dimension props(nprops), density(nblock), coordMp(nblock,*),

1 charLength(nblock), strainInc(nblock,ndir+nshr),

2 relSpinInc(nblock,nshr), tempOld(nblock),

3 stretchOld(nblock,ndir+nshr),

4 defgradOld(nblock,ndir+nshr+nshr),

5 fieldOld(nblock,nfieldv), stressOld(nblock,ndir+nshr),

6 stateOld(nblock,nstatev), enerInternOld(nblock),

7 enerInelasOld(nblock), tempNew(nblock),

8 stretchNew(nblock,ndir+nshr),

8 defgradNew(nblock,ndir+nshr+nshr),

9 fieldNew(nblock,nfieldv),

1 stressNew(nblock,ndir+nshr), stateNew(nblock,nstatev),

2 enerInternNew(nblock), enerInelasNew(nblock),

C

character*80 cmname

C

do 100 km = 1,nblock

user coding

100 continue

return

end

Variables to be defined 被定义的变量

stressNew (nblock, ndir+nshr)

Stress tensor at each material point at the end of the increment.

在增量结束时每个材料点的应力张量。

stateNew (nblock, nstatev)

State variables at each material point at the end of the increment. You define the size of this array by allocating space for it (see “User subroutines: overview,” Section 25.1.1, for more information).

增量结束时每个材料点的状态变量。用户通过分配空间来定义该矩阵的大小（更多的资料参考“User subroutines: overview,” Section 25.1.1）。

Variables that can be updated 可以更新的变量

enerInternNew (nblock)

Internal energy per unit mass at each material point at the end of the increment.

增量结束时每个材料点单位质量的内能。

enerInelasNew (nblock)

Dissipated inelastic energy per unit mass at each material point at the end of the increment.

增量结束时每个材料点单位质量的消散的无弹性能。

Variables passed in for information

nblock

Number of material points to be processed in this call to VUMAT.

调用VUMAT的材料点号。

ndir

Number of direct components in a symmetric tensor.

对成张量的直接分量号。

nshr

Number of indirect components in a symmetric tensor.

对称张量的间接分量号。

nstatev

Number of user-defined state variables that are associated with this material type (you define this as described in “Allocating space” in “User subroutines: overview,” Section 25.1.1).

与材料类型相关的用户定义状态变量号。

nfieldv

Number of user-defined external field variables.

用户定义外部场变量号。

nprops

User-specified number of user-defined material properties.

用户定义材料属性的用户指定号。

lanneal

Flag indicating whether the routine is being called during an annealing process. lanneal=0 indicates that the routine is being called during a normal mechanics increment. lanneal=1 indicates that this is an annealing process and you should re-initialize the internal state variables, stateNew, if necessary. ABAQUS/Explicit will automatically set the stresses, stretches, and state to a value of zero during the annealing process.

在退火处理过程中标示程序是否被调用。Laneal=0表明程序在正常力学增量过程中被调用。Laneal＝1表明这是一个退火过程，并且如果需要的话用户需要重新初始化内部状态变量stateNew。ABAQUS/Explicit将自动设置应力，延展性及在退火过程中0值状态。

stepTime

Value of time since the step began.

从时间步开始时的的时间

totalTime

Value of total time. The time at the beginning of the step is given by totalTime - stepTime.

总时间值。时间步开始时的时间定义为totalTime - stepTime

dt

Time increment size.

时间增量大小。

cmname

User-specified material name, left justified. It is passed in as an upper-case character string. Some internal material models are given names starting with the “ABQ_” character string. To avoid conflict, you should not use “ABQ_” as the leading string for cmname.

用户指定材料名。按照大写字母传入。有些内部材料本构以ABQ_字母开头赋名。为了避免冲突，用户不能使用ABQ_作为cmname的开头字母。

coordMp(nblock,*)

Material point coordinates. It is the midplane material point for shell elements and the centroid for beam elements.

材料点坐标。对于壳单元为中平面材料点，对于梁单元为质心。

charLength(nblock)

Characteristic element length. This is a typical length of a line across an element. For beams and trusses, it is a characteristic length along the element axis. For membranes and shells, it is a characteristic length in the reference surface. For axisymmetric elements, it is a characteristic length in the – plane only. For cohesive elements it is equal to the constitutive thickness.

特征单元长度。它是一个穿过单元线的特殊长度。对于梁及桁架，它表示沿单元轴的特征长度。对于膜及壳，它表示参考面上的特征长度。对于对称单元，它仅仅表示–平面上的特征长度。对于粘聚单元它等于结构厚度。

props(nprops)

User-supplied material properties.

用户指定材料属性

density(nblock)

Current density at the material points in the midstep configuration. This value may be inaccurate in problems where the volumetric strain increment is very small. If an accurate value of the density is required in such cases, the analysis should be run in double precision. This value of the density is not affected by mass scaling.

材料点的当前密度。在体积应变增量非常小的情况下，该值可能出现精确性问题。在这种情况下如果需要精确的密度值，分析需要在双精度下运行。密度值不受质量缩放比例的影响

strainInc (nblock, ndir+nshr)

Strain increment tensor at each material point.

每个材料点的应变增量张量。

relSpinInc (nblock, nshr)

Incremental relative rotation vector at each material point defined in the corotational system. Defined as , where is the antisymmetric part of the velocity gradient, , and . Stored in 3-D as and in 2-D as .

定义在联合旋转系中的每个材料点的增量相关选择矢量。定义为，其中为速度剃度，的反对称部分，在三维条件下存储为，在二维条件下存储为。

tempOld(nblock)

Temperatures at each material point at the beginning of the increment.

增量开始时每个材料点的温度。

stretchOld (nblock, ndir+nshr)

Stretch tensor, , at each material point at the beginning of the increment defined from the polar decomposition of the deformation gradient by .

增量开始时每个材料点的，拉伸张量。

defgradOld (nblock,ndir+2*nshr)

Deformation gradient tensor at each material point at the beginning of the increment. Stored in 3-D as (, , , , , , , , ) and in 2-D as (, , , , ).

增量开始时每个材料点的位移剃度张量。在三维状态下存储为(, , , , , , , , ) 及在二维条件下存储为(, , , , ).

fieldOld (nblock, nfieldv)

Values of the user-defined field variables at each material point at the beginning of the increment.

.增量开始时每个材料点的用户定义场变量值。

stressOld (nblock, ndir+nshr)

Stress tensor at each material point at the beginning of the increment.

增量开始时每个材料点的应力张量。

stateOld (nblock, nstatev)

State variables at each material point at the beginning of the increment.

增量开始时每个材料点的状态变量。

enerInternOld (nblock)

Internal energy per unit mass at each material point at the beginning of the increment.

增量开始时每个材料点的单位质量的内能

enerInelasOld (nblock)

Dissipated inelastic energy per unit mass at each material point at the beginning of the increment.

增量开始时每个材料点的单位质量消散的无弹性能。

tempNew(nblock)

Temperatures at each material point at the end of the increment.

增量开始时每个材料点的温度。

stretchNew (nblock, ndir+nshr)

Stretch tensor, , at each material point at the end of the increment defined from the polar decomposition of the deformation gradient by .

defgradNew (nblock,ndir+2*nshr)

Deformation gradient tensor at each material point at the end of the increment. Stored in 3-D as (, , , , , , , , ) and in 2-D as (, , , , ).

增量结束时每个材料点的位移剃度张量。三维状态下存储为(, , , , , , , , ) ，二维状态下存储为 (, , , , )。

fieldNew (nblock, nfieldv)

Values of the user-defined field variables at each material point at the end of the increment.

增量结束时每个材料点的用户指定场变量值。

Example: Using more than one user-defined material model

例子：使用多个用户定义材料模型

To use more than one user-defined material model, the variable cmname can be tested for different material names inside user subroutine VUMAT, as illustrated below:

要使用多种用户材料模型，用户子程序VUMAT中使用cmname值代表不同的材料名，如下所述：

if (cmname(1:4) .eq. 'MAT1') then

call VUMAT_MAT1(argument_list)

else if (cmname(1:4) .eq. 'MAT2') then

call VUMAT_MAT2(argument_list)

end if

VUMAT_MAT1 and VUMAT_MAT2 are the actual user material subroutines containing the constitutive material models for each material MAT1 and MAT2, respectively. Subroutine VUMAT merely acts as a directory here. The argument list can be the same as that used in subroutine VUMAT. The material names must be in upper case since cmname is passed in as an upper-case character string.

VUMAT_MAT1 and VUMAT_MAT2分别为实际的包含MAT1及MAT2材料本构的用户材料子程序。子程序VUMAT在此仅仅作为一个地址。

Example: Elastic/plastic material with kinematic hardening

例子：带有运动硬化的弹性/塑性材料

As a simple example of the coding of subroutine VUMAT, consider the generalized plane strain case for an elastic/plastic material with kinematic hardening. The basic assumptions and definitions of the model are as follows.

作为子程序VUMAT的简单例子代码，考虑通用运动硬化弹性/塑性材料的平面应变问题。模型的基本假设及定义如下。

Let be the current value of the stress and define to be the deviatoric part of the stress. The center of the yield surface in deviatoric stress space is given by the tensor , which has initial values of zero. The stress difference, , is the stress measured from the center of the yield surface and is given by

设定为应力的当前值，并定义应力的偏量部分。在偏应力空间屈服面中心由张量给定，其初始值为0。应力导数为从屈服面中学测量的应力，由给出。

The von Mises yield surface is defined as Mises屈服面定义为

where is the uniaxial equivalent yield stress. The von Mises yield surface is a cylinder in deviatoric stress space with a radius of

为单轴等效屈服应力，在偏应力空间中Mises屈服面是一个以为半径的圆柱。

For the kinematic hardening model, is a constant. The normal to the Mises yield surface can be written as

对于运动硬化模型，是一个常数。Mises屈服面的法线定义为

We decompose the strain rate into an elastic and plastic part using an additive decomposition:

将应变率分解为弹性和塑性部分：

The plastic part of the strain rate is given by a normality condition

塑性应变率由给出

where the scalar multiplier must be determined. A scalar measure of equivalent plastic strain rate is defined by

式中必须指定比例乘子。等效塑性应变率比例量测定义为

The stress rate is assumed to be purely due to the elastic part of the strain rate and is expressed in terms of Hooke's law by

where and are the Lamés constants for the material.

假定应力率完全是由弹性应变率引起，并且由Hooke定律表示为

式中及是材料的拉枚常数。

The evolution law for is given as

where is the slope of the uniaxial yield stress versus plastic strain curve.

的发展准则定义为

式中，单轴屈服应力与塑性应变曲线的斜率

During active plastic loading the stress must remain on the yield surface, so that

在激活塑性荷载是应力必须保持在屈服面上，所以

The equivalent plastic strain rate is related to by

等效塑性应变率通过式与 相关。

The kinematic hardening constitutive model is integrated in a rate form as follows. A trial elastic stress is computed as

where the subscripts and refer to the beginning and end of the increment, respectively. If the trial stress does not exceed the yield stress, the new stress is set equal to the trial stress. If the yield stress is exceeded, plasticity occurs in the increment. We then write the incremental analogs of the rate equations as

where

From the definition of the normal to the yield surface at the end of the increment, ,

This can be expanded using the incremental equations as

Taking the tensor product of this equation with , using the the yield condition at the end of the increment, and solving for :

The value for is used in the incremental equations to determine , , and .

This algorithm is often referred to as an elastic predictor, radial return algorithm because the correction to the trial stress under the active plastic loading condition returns the stress state to the yield surface along the direction defined by the vector from the center of the yield surface to the elastic trial stress. The subroutine would be coded as follows:

subroutine vumat(

C Read only –只读

1 nblock, ndir, nshr, nstatev, nfieldv, nprops, lanneal,

2 stepTime, totalTime, dt, cmname, coordMp, charLength,

3 props, density, strainInc, relSpinInc,

4 tempOld, stretchOld, defgradOld, fieldOld,

3 stressOld, stateOld, enerInternOld, enerInelasOld,

6 tempNew, stretchNew, defgradNew, fieldNew,

C Write only –只写

5 stressNew, stateNew, enerInternNew, enerInelasNew )

C

include 'vaba_param.inc'

C

C J2 Mises Plasticity with kinematic hardening for plane

C strain case.平面应变状态下带有运动硬化的Mises塑性

C Elastic predictor, radial corrector algorithm.

C

C The state variables are stored as:

C STATE(*,1) = back stress component 11

C STATE(*,2) = back stress component 22

C STATE(*,3) = back stress component 33

C STATE(*,4) = back stress component 12

C STATE(*,5) = equivalent plastic strain 等效塑性应变

C

C

C All arrays dimensioned by (*) are not used in this algorithm

dimension props(nprops), density(nblock),

1 coordMp(nblock,*),

2 charLength(*), strainInc(nblock,ndir+nshr),

3 relSpinInc(*), tempOld(*),

4 stretchOld(*), defgradOld(*),

5 fieldOld(*), stressOld(nblock,ndir+nshr),

6 stateOld(nblock,nstatev), enerInternOld(nblock),

7 enerInelasOld(nblock), tempNew(*),

8 stretchNew(*), defgradNew(*), fieldNew(*),

9 stressNew(nblock,ndir+nshr), stateNew(nblock,nstatev),

1 enerInternNew(nblock), enerInelasNew(nblock)

C

character*80 cmname

C

parameter( zero = 0., one = 1., two = 2., three = 3.,

1 third = one/three, half = .5, twoThirds = two/three,

2 threeHalfs = 1.5 )

C

e = props(1)

xnu = props(2)

yield = props(3)

hard = props(4)

C

twomu = e / ( one + xnu )

thremu = threeHalfs * twomu

sixmu = three * twomu

alamda = twomu * ( e - twomu ) / ( sixmu - two * e )

term = one / ( twomu * ( one + hard/thremu ) )

con1 = sqrt( twoThirds )

C

do 100 i = 1,nblock

C

C Trial stress

trace = strainInc(i,1) + strainInc(i,2) + strainInc(i,3)

sig1 = stressOld(i,1) + alamda*trace + twomu*strainInc(i,1)

sig2 = stressOld(i,2) + alamda*trace + twomu*strainInc(i,2)

sig3 = stressOld(i,3) + alamda*trace + twomu*strainInc(i,3)

sig4 = stressOld(i,4) + twomu*strainInc(i,4)

C

C Trial stress measured from the back stress

s1 = sig1 - stateOld(i,1)

s2 = sig2 - stateOld(i,2)

s3 = sig3 - stateOld(i,3)

s4 = sig4 - stateOld(i,4)

C

C Deviatoric part of trial stress measured from the back stress

smean = third * ( s1 + s2 + s3 )

ds1 = s1 - smean

ds2 = s2 - smean

ds3 = s3 - smean

C

C Magnitude of the deviatoric trial stress difference

dsmag = sqrt( ds1**2 + ds2**2 + ds3**2 + 2.*s4**2 )

C

C Check for yield by determining the factor for plasticity,

C zero for elastic, one for yield

radius = con1 * yield

facyld = zero

if( dsmag - radius .ge. zero ) facyld = one

C

C Add a protective addition factor to prevent a divide by zero

C when dsmag is zero. If dsmag is zero, we will not have exceeded

C the yield stress and facyld will be zero.

dsmag = dsmag + ( one - facyld )

C

C Calculated increment in gamma (this explicitly includes the

C time step)

diff = dsmag - radius

dgamma = facyld * term * diff

C

C Update equivalent plastic strain

deqps = con1 * dgamma

stateNew(i,5) = stateOld(i,5) + deqps

C

C Divide dgamma by dsmag so that the deviatoric stresses are

C explicitly converted to tensors of unit magnitude in the

C following calculations

dgamma = dgamma / dsmag

C

C Update back stress

factor = hard * dgamma * twoThirds

stateNew(i,1) = stateOld(i,1) + factor * ds1

stateNew(i,2) = stateOld(i,2) + factor * ds2

stateNew(i,3) = stateOld(i,3) + factor * ds3

stateNew(i,4) = stateOld(i,4) + factor * s4

C

C Update the stress

factor = twomu * dgamma

stressNew(i,1) = sig1 - factor * ds1

stressNew(i,2) = sig2 - factor * ds2

stressNew(i,3) = sig3 - factor * ds3

stressNew(i,4) = sig4 - factor * s4

C

C Update the specific internal energy -

stressPower = half * (

1 ( stressOld(i,1)+stressNew(i,1) )*strainInc(i,1)

1 + ( stressOld(i,2)+stressNew(i,2) )*strainInc(i,2)

1 + ( stressOld(i,3)+stressNew(i,3) )*strainInc(i,3)

1 + two*( stressOld(i,4)+stressNew(i,4) )*strainInc(i,4) )

C

enerInternNew(i) = enerInternOld(i)

1 + stressPower / density(i)

C

C Update the dissipated inelastic specific energy -

smean = third * ( stressNew(i,1) + stressNew(i,2)

1 + stressNew(i,3) )

equivStress = sqrt( threeHalfs *

1 ( (stressNew(i,1)-smean)**2

1 + (stressNew(i,2)-smean)**2

1 + (stressNew(i,3)-smean)**2

1 + two * stressNew(i,4)**2 ) )

plasticWorkInc = equivStress * deqps

enerInelasNew(i) = enerInelasOld(i)

1 + plasticWorkInc / density(i)

100 continue

C

return

end

本文来源：https://www.2haoxitong.net/k/doc/d00f344e767f5acfa1c7cd1f.html